gBackup - [2] :: Программы :: Компьютерный форум Ru.Board

С FTP всё просто, никаких специальных программ не нужно, на просторах интеренета нашёл скрипты для закачивания и скачивания с FTP и адаптировал под свои нужды.
Например если нужно переправить с работы домой все изменения в файлах за рабочий день, то делаем следующее:
1. Перед началом работы запускаем архивацию со следующими параметрами:
D:\Backup\gbackup.exe d:\Работа D:\Backup\Rabota -n99 -rar4 -i -s
В результате выполнения этой команды в папке "D:\Backup\Rabota" будет создан только список файлов в файле "arhiv.spv", таким образом мы создали точку отсчёта. В последствии будут сохранены все изменения, начиная с этого момента.
2. По окончании рабочего дня запускаем ту же команду и с теми же параметрами из п.1. Если нужно зафиксировать промежуточные изменения, то можно запускать команду многократно в течение рабочего дня (до 99 раз). В результате мы получим инкрементный(е) архив(ы) в конечной папке "D:\Backup\Rabota".
3. Теперь нужно содержимое папки "D:\Backup\Rabota" закачать на FTP. Запускаем скрипт следующего содержания:

Код:

ECHO OFF
SET PTH=d:\Backup\Rabota

:: ~Параметры соединения
SET FTPS=server_ftp
SET USER=login
SET PASS=parol'
:: ~Путь на Ftp
SET FPATH=/dokum_/
SET NPATH=/dokum/
:: ~Имя временного файла
SET FTMP=%~dp0ftp.tmp

:: Удаляем временный каталог на FTP :: Собираем TMP-файл
Echo open %FTPS%>%FTMP%
Echo user %USER%>>%FTMP%
Echo %PASS%>>%FTMP%
Echo mdelete %FPATH%*>>%FTMP%
Echo rmdir %FPATH%>>%FTMP%
Echo bye>>%FTMP%
:: Запуск
FTP -v -i -n -s:%FTMP%
DEL %FTMP%

:: Создаем временный каталог на FTP :: Собираем TMP-файл
Echo open %FTPS%>%FTMP%
Echo user %USER%>>%FTMP%
Echo %PASS%>>%FTMP%
Echo mkdir %FPATH%>>%FTMP%
Echo bye>>%FTMP%
:: Запуск
FTP -v -i -n -s:%FTMP%
DEL %FTMP%

:: Читаем файлы каталога
FOR %%f IN (%PTH%\*.rar) DO CALL :upl %%f
CALL :upl %PTH%\Restore.cmd

:: Удаляем каталог на FTP :: Собираем TMP-файл
Echo open %FTPS%>%FTMP%
Echo user %USER%>>%FTMP%
Echo %PASS%>>%FTMP%
Echo mdelete %NPATH%*>>%FTMP%
Echo rmdir %NPATH%>>%FTMP%
Echo bye>>%FTMP%
:: Запуск
FTP -v -i -n -s:%FTMP%
DEL %FTMP%

:: Переименовываем временный каталог на FTP :: Собираем TMP-файл
Echo open %FTPS%>%FTMP%
Echo user %USER%>>%FTMP%
Echo %PASS%>>%FTMP%
Echo rename %FPATH% %NPATH%>>%FTMP%
Echo bye>>%FTMP%
:: Запуск
FTP -v -n -s:%FTMP%
DEL %FTMP%
EXIT

:upl
:: Закачиваем файлы во временный каталог на FTP :: Собираем TMP-файл
Echo open %FTPS%>%FTMP%
Echo user %USER%>>%FTMP%
Echo %PASS%>>%FTMP%
Echo cd %FPATH%>>%FTMP%
Echo binary>>%FTMP%
Echo put %1>>%FTMP%
Echo bye>>%FTMP%
:: Запуск
FTP -v -n -s:%FTMP%
DEL %FTMP%
Exit /b

4. Теперь, дома нам нужно скачать с FTP архивы. Запускаем скрипт следующего содержания:

Код:

@echo off
:: ~Параметры соединения
Set FTPS=server_ftp
Set USER=login
Set PASS=parol'
:: ~Путь на Ftp
SET FPATH=/dokum/
:: ~Локальный Путь
SET LPATH=С:\arh
:: ~Имя временного файла
Set FTMP=%~dp0ftp.tmp

IF EXIST %LPATH% RMDIR /s /q %LPATH%
MD %LPATH%

:: Собираем TMP-файл
>%FTMP% (
Echo open %FTPS%
Echo user %USER%
Echo %PASS%
Echo cd %FPATH%
Echo lcd %LPATH%
Echo binary
Echo prompt
Echo mget *
Echo bye
)
:: Запуск
FTP -v -n -s:%FTMP%
del %FTMP%

COPY d:\Backup\gBackup.exe %LPATH%
CALL %LPATH%\Restore.cmd "d:\dokuments"

RMDIR /s /q %LPATH%

В результате работы скрипта все новые файлы будут скачаны и распакованы в папку "d:\dokuments" (с заменой старых и удалением не нужных).
В обратную сторону можно организовать аналогичный процесс.

Модерирует : gyra, Maz
Версия для печати • Подписаться • Добавить в закладки
Страницы: 1 2 3 4 5 6 7 8