mat86
Full Member | Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
@echo off
:st
echo Доступные диски:
For %%I IN (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) DO for /f "tokens=4,5*" %%k in ('vol %%I: 2^>nul^|find "устройстве"') do echo %%k - %%l %%m
set newd=%HBCD:~0,1%
for /f "tokens=3" %%x in ('fsutil fsinfo drivetype %newd%:') do if "%%x"=="CD-ROM" set newd=C
echo Нажмите ENTER если Вы хотите создать папку temp в %newd%:\$HBCDTmp
set /p newd=Введите только букву диска (например, %newd%) :
set NewTemp=%newd%:\$HBCDTmp
if /i %TEMP%==%NewTemp% if /i %TMP%==%NewTemp% if not exist "B:\" if exist "%Temp%\" goto alrd
if not exist "%NewTemp%\" goto cont1
echo Новая временная папка temp уже существует
if not exist "%NewTemp%\*" goto cont2
echo Пожалуйста подождите, идет очистка содержимого...
rmdir /s /q %NewTemp% 2> NUL
if exist "%NewTemp%\*" (echo Некоторые файлы/папки не могут быть удалены из новой временной папки!) else echo Содержимое новой временной папки очищено...
if exist "%NewTemp%\" (goto cont2) else goto ncm
:cont1
echo Создание новой временной папки temp...
:ncm
mkdir %NewTemp% 2> NUL
if not exist "%NewTemp%\" goto err2
:cont2
for /f "tokens=3" %%i in ('dir /-c %newd%:\ ^| find "байт свободно"') do if %%i lss 209715200 goto err3
if not exist "B:\" goto cont3
echo Отключение диска B...
imdisk.exe -D -m B:
if exist "B:\" then goto err4
:cont3
if /i %TEMP%==%NewTemp% if /i %TMP%==%NewTemp% goto cont4
echo Настройка окружения...
setx.exe Temp %NewTemp%
if errorlevel 1 goto err5
setx.exe Tmp %NewTemp%
if errorlevel 1 goto err5
set Temp=%NewTemp%
set Tmp=%NewTemp%
echo Настройка Program files на %SystemDrive%...
Reg add HKLM\Software\Microsoft\Windows\CurrentVersion /f /t REG_EXPAND_SZ /v ProgramFilesDir /d "%SystemDrive%\Program Files" >nul
Reg add HKLM\Software\Microsoft\Windows\CurrentVersion /f /t REG_EXPAND_SZ /v ProgramFilesPath /d "%SystemDrive%\Program Files" >nul
Reg add HKLM\Software\Microsoft\Windows\CurrentVersion /f /t REG_EXPAND_SZ /v CommonFilesDir /d "%SystemDrive%\Program Files\Common Files" >nul
mkdir "%SystemDrive%\Program Files\Common Files"
setx.exe ramdrv %Temp% -m
if errorlevel 1 goto err5
nircmd sysrefresh 2> NUL
nircmd sysrefresh environment 2> NUL
if not exist "%HBCD%\HBCD\HBCDmenu.exe" goto err6
echo Перезапуск HBCD menu...
nircmd closeprocess HBCDmenu.exe 2> NUL
nircmd killprocess HBCDmenu.exe 2> NUL
start "HBCD menu" /MIN "%HBCD%\HBCD\HBCDmenu.exe" 2> NUL
if errorlevel 1 goto err7
:cont4
goto ok
:alrd
echo Папка temp уже существует на загрузочном диске!
goto end
:err2
echo Новая папка temp %NewTemp% не может быть (пере)создана!
echo.
goto st
:err3
echo Объем свободного места на диске %NewTemp:~0,2% меньше 200 Мб!
echo Освободите еще и попробуйте снова...
goto end
:err4
echo Диск B не может быть отключен!
goto end
:err5
echo Окружение не задано!
goto end
:err6
echo Не найден "%HBCD%\HBCD\HBCDmenu.exe"
echo Пожалуйста перезапустите HBCD menu вручную!
goto ok
:err7
echo Error starting "%HBCD%\HBCD\HBCDmenu.exe"
echo Пожалуйста перезапустите HBCD menu вручную!
goto ok
 k
echo Папка Temp теперь в %Temp%
for /f "tokens=3" %%x in ('fsutil fsinfo drivetype %newd%:') do if "%%x"=="Жесткий" nircmd qbox "Настроить pagefile как~n%newd%:\pagefile.sys размером 512 Mб?" "Настроить Pagefile" "SetPageFile.exe" %newd%:\pagefile.sys 512
:end
pause |
Всего записей: 438 | Зарегистр. 19-03-2009 | Отправлено: 01:16 06-01-2013 | Исправлено: mat86, 01:23 06-01-2013 |
|
