nik1967
Advanced Member | Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Код: [Setup]
AppName=My Program
AppVerName=My Program
DefaultDirName={pf}\My Program
DefaultGroupName=My Program
OutputDir=.
Uninstallable=not MyRadioBtnChecked
[Languages]
Name: ru; MessagesFile: compiler:Languages\Russian.isl;
[Tasks]
; Дополнительно
; Ярлык(и) на «Рабочем столе»
Name: "desktopicon"; Description: "Ярлык(и) на «Рабочем столе»"; GroupDescription: "Дополнительно:"; Flags: checkedonce; Check: not MyRadioBtnChecked
; Ярлыки в меню «Пуск»
Name: "starticon"; Description: "Ярлыки в меню «Пуск»"; GroupDescription: "Дополнительно:"; Flags: checkedonce; Check: not MyRadioBtnChecked
[Icons]
Name: "{group}\My Program"; Filename: "{uninstallexe}"; Tasks: starticon; Check: not MyRadioBtnChecked
Name: "{commondesktop}\My Program"; Filename: "{uninstallexe}"; Tasks: desktopicon; Check: not MyRadioBtnChecked
[Files]
; Файлы для проверки и демонстрации. При реальном использовании - закомментировать или удалить!
Source: {win}\Help\*; DestDir: {app}; Flags: external recursesubdirs
[CustomMessages]
HeaderLabelPage=Выберите тип установки:
MyRadioCaption_1=Распаковка портативной версии
MyRadioCaption_2=Установка обычной версии (рекомендуется)
[UninstallDelete]
Type: filesandordirs; Name: {app}
[_code]
var
MyRadioBtn_1, MyRadioBtn_2: TNewRadioButton;
function MyRadioBtnChecked: boolean;
begin
Result:= MyRadioBtn_1.Checked;
end;
procedure RadBtnOnClick(Sender: TObject);
begin
case Sender of
MyRadioBtn_1: WizardForm.DirEdit.Text:= ExpandConstant('{src}')+'\My Program Portable';
MyRadioBtn_2: WizardForm.DirEdit.Text:= ExpandConstant('{#SetupSetting("DefaultDirName")}');
end;
end;
procedure InitializeWizard();
begin
with TNewStaticText.Create(WizardForm) do begin
Width:= WizardForm.InnerNotebook.Width;
Top:= ScaleY(120);
Height:= ScaleY(26);
WordWrap:= True;
Caption:= ExpandConstant('{cm:HeaderLabelPage}');
Parent:= WizardForm.SelectDirPage;
end;
MyRadioBtn_1 := TNewRadioButton.Create(WizardForm);
with MyRadioBtn_1 do
begin
Top:= ScaleY(140);
Left:= ScaleX(5);
Width:= ScaleX(200);
Caption:= ExpandConstant('{cm:MyRadioCaption_1}');
OnClick:= @RadBtnOnClick;
Parent:= WizardForm.SelectDirPage;
end;
MyRadioBtn_2 := TNewRadioButton.Create(WizardForm);
with MyRadioBtn_2 do
begin
Top:= ScaleY(160);
Left:= ScaleX(5);
Width:= ScaleX(260);
Caption:= ExpandConstant('{cm:MyRadioCaption_2}');
OnClick:= @RadBtnOnClick;
Checked:= True;
Parent:= WizardForm.SelectDirPage;
end;
end;
function ShouldSkipPage(PageID: Integer): Boolean;
begin
Result:= (PageID > wpSelectDir) and (PageID < wpInstalling) and (MyRadioBtn_1.Checked);
end; |
|
Всего записей: 1076 | Зарегистр. 11-10-2006 | Отправлено: 12:43 18-11-2013 | Исправлено: nik1967, 13:31 18-11-2013 |
|
